Функция dateBetween – разница между датами | Формулы Notion 2.0

Синтаксис

dateBetween(date, date, unit)

date: Обязательный аргумент (Date). Уменьшаемая дата. Может содержать обращение к свойству базы данных с датой, а также функцию, возвращающую дату.
date: Обязательный аргумент (Date). Вычитаемая дата. Может содержать обращение к свойству базы данных с датой, а также функцию, возвращающую дату.
unit: Обязательный аргумент (Text). Ключ единицы измерения времени. Может содержать строковый литерал, обращение к свойству базы данных с текстом, а также функцию, возвращающую текст.

Возвращает Number.

Хотите чувствовать себя в Notion как рыба в воде?

Подпишитесь на канал автора сайта «Формулы Notion 2.0» с обзорами новых функций, советами начинающим и продвинутым пользователям, шаблонами, видеоуроками и эксклюзивными формулами! Перейти

Ключи

Функция Notion dateBetween поддерживает следующие ключи (единицы измерения времени):

years, year – год;
quarters, quarter – квартал;
months, month – месяц;
weeks, week – неделя;
days, day – день;
hours, hour – час;
minutes, minute – минута.

25 формул Notion на каждый день

Бесплатный шаблон для Notion с подборкой из 25 востребованных формул от автора сайта «Формулы Notion 2.0». Перейти

Использование

Принцип работы dateBetween (продолжительность, длительность)

/* https://notionformulas.chumakova.ru */dateBetween(
	prop("Дата окончания"), /* Дата, из которой нужно вычесть */
	prop("Дата начала"), /* Дата, которую надо вычесть */
	"days" /* Единицы (ключ) */
)

/* https://notionformulas.chumakova.ru */dateBetween(prop("Дата окончания"), prop("Дата начала"), "day")

/* https://notionformulas.chumakova.ru */prop("Дата окончания").dateBetween(prop("Дата начала"), "days")

/* https://notionformulas.chumakova.ru */prop("Дата окончания").dateBetween(prop("Дата начала"), "day")

Формула Notion 2.0 «Принцип работы dateBetween (продолжительность, длительность)»

В этой формуле используется prop.

Дней в интервале (продолжительность, длительность)

/* https://notionformulas.chumakova.ru */dateBetween(
	dateEnd(prop("Интервал")),
	dateStart(prop("Интервал")),
	"days"
)

/* https://notionformulas.chumakova.ru */prop("Интервал").dateEnd().dateBetween(
	prop("Интервал").dateStart(),
	"days"
)

Формула Notion 2.0 «Дней в интервале (продолжительность, длительность)»

В этой формуле используются: prop, dateEnd, dateStart.

Длительность сеанса в часах и минутах (учет времени)

Данная формула подробно рассматривается в видео «Учет времени в Notion».

/* https://notionformulas.chumakova.ru */lets(
	total, dateBetween(prop("Окончание"), prop("Начало"), "minutes"),
	hours, (total / 60).floor(),
	minutes, total % 60,
	[
		(hours > 0).if(hours + " час.", ""),
		(minutes > 0).if(minutes + " мин.", "")
	].filter(current.empty().not()).join(" ")
)

Формула Notion 2.0 «Длительность сеанса в часах и минутах (учет времени)»

В этой формуле используются: lets, prop, /, floor, %, >, if, + (сложение), filter, empty, not, join.

Преобразование диапазона дат в список (массив) дат

Для данной формулы доступен только предпросмотр. Формула предназначена для демонстрации возможностей Notion. Научиться писать сложные формулы Notion можно в ходе онлайн-курса «Формулы Notion 2.0» от автора этого справочника.

Продолжительность в годах, месяцах и днях (стаж сотрудника)

Скриншот от 12.06.2024.

Возраст сотрудников

/* https://notionformulas.chumakova.ru */dateBetween(today(), prop("Дата рождения"), "years")

/* https://notionformulas.chumakova.ru */today().dateBetween(prop("Дата рождения"), "years")

Формула Notion 2.0 «Возраст сотрудников»

Имена людей – вымышленные.

В этой формуле используется prop.

Дни рождения сотрудников

Скриншот от 28.06.2024.

Имена людей – вымышленные.

Автостатус с просрочкой в днях

/* https://notionformulas.chumakova.ru */lets(
	interval, dateBetween(
		prop("Крайний срок").formatDate("YYYYMMDD").parseDate(), 
		today(), 
		"days"
	),
	sign, interval.sign(),
	ifs(
		sign == -1, ("Просрочена на " + interval.abs() + " дн.").style("red"),
		sign == 1, "В запасе " + interval + " дн.",
		sign == 0, "Крайний срок – сегодня",
		""
	)
)