Функция let – пользовательская переменная | Формулы Notion 2.0

Синтаксис

let(variable, value, expression)

variable: Обязательный аргумент (Variable). Имя пользовательской переменной.
value: Обязательный аргумент (Value). Значение, присваемое переменной.
expression: Обязательный аргумент (Value). Действия с использованием переменной.

Возвращает Value.

Хотите чувствовать себя в Notion как рыба в воде?

Подпишитесь на канал автора сайта «Формулы Notion 2.0» с обзорами новых функций, советами начинающим и продвинутым пользователям, шаблонами, видеоуроками и эксклюзивными формулами! Перейти

Особенности

Переменная, объявленная в рамках функции Notion let, существует только в пределах данного вызова функции. Попытка обратиться к ней вне данного вызова функции let приводит к возникновению ошибки.

Функция Notion let может вызываться несколько раз в одной формуле.

Функция Notion let не поддерживает альтернативную запись с использованием оператора «точка».

Для создания нескольких пользовательских переменных вместо функции Notion let рекомендуется использовать функцию lets.

25 формул Notion на каждый день

Бесплатный шаблон для Notion с подборкой из 25 востребованных формул от автора сайта «Формулы Notion 2.0». Перейти

Использование

Принцип работы let

/* https://notionformulas.chumakova.ru */let(
	num, /* Имя переменной */
	prop("Число"), /* Значение переменной */
	num * 2 /* Действие с использованием переменной */
)

В этой формуле используются: prop, *.

Проверка на наличие подстроки в строке (протокол сайта)

/* https://notionformulas.chumakova.ru */let(
	url, prop("URL"),
	ifs(
		url.contains("https://"), "👍 Защищен",
		url.contains("http://"), "🚫 Не защищен".style("grey"),
		"Введите протокол!".style("red")
	)
)

В этой формуле используются: prop, ifs, contains, style.

Сегодня в диапазоне?

/* https://notionformulas.chumakova.ru */let(
	format, "YYYYMMDD",
	prop("Дата").dateStart().formatDate(format).parseDate() <= today() &&
	today() <= prop("Дата").dateEnd().formatDate(format).parseDate()
)

Скриншот от 09.06.2024

В этой формуле используются: prop, dateStart, formatDate, parseDate, <=, today, && (and), dateEnd.