Функция today – текущая дата | Формулы Notion 2.0

Синтаксис

today()

Возвращает Date.

Хотите чувствовать себя в Notion как рыба в воде?

Подпишитесь на канал автора сайта «Формулы Notion 2.0» с обзорами новых функций, советами начинающим и продвинутым пользователям, шаблонами, видеоуроками и эксклюзивными формулами! Перейти

Особенности

Вывод функции today обновляется динамически в соответствии с текущей датой (при открытии или перезагрузке страницы, редактировании базы данных). Пытаться использовать ее для фиксации даты того или иного события (например, смены статуса или состояния чекбокса) бессмысленно.

Если при осуществлении манипуляций с датами необходимо вывести не только дату, но и время, необходимо использовать функцию now.

Поскольку функция Notion today не принимает аргументов, она не поддерживает альтернативную запись с использованием оператора «точка».

25 формул Notion на каждый день

Бесплатный шаблон для Notion с подборкой из 25 востребованных формул от автора сайта «Формулы Notion 2.0». Перейти

Использование

Функция Notion today чаще всего используется в формулах, обрабатывающих даты в системах управления задачами (task management) и проектами (project management).

Принцип работы today (текущая дата без времени)

/* https://notionformulas.chumakova.ru */today()

Скриншот от 14.06.2024 08:37.

Автостатус с просрочкой в днях

/* https://notionformulas.chumakova.ru */lets(
	interval, dateBetween(
		prop("Крайний срок").formatDate("YYYYMMDD").parseDate(), 
		today(), 
		"days"
	),
	sign, interval.sign(),
	ifs(
		sign == -1, ("Просрочена на " + interval.abs() + " дн.").style("red"),
		sign == 1, "В запасе " + interval + " дн.",
		sign == 0, "Крайний срок – сегодня",
		""
	)
)

Скриншот от 09.06.2024.

В этой формуле используются: lets, dateBetween, prop, formatDate, parseDate, sign, ifs, ==, abs, style, + (сложение).

Текущая дата – конечная дата диапазона

Формула устанавливает сегодняшний день в качестве дня окончания диапазона, если задача не была выполнена. Таким образом, задачи, которые не были выполнены, не пропадают из поля зрения на диаграмме Ганта (Timeline view).

/* https://notionformulas.chumakova.ru */prop("Выполнена").empty().not().if(
	prop("Сроки"),
	lets(
		ed, prop("Сроки").dateEnd(),
		td, today(),
		(td <= ed).if(
			prop("Сроки"),
			dateRange(prop("Сроки").dateStart(), today())
		)
	)
)

Формула Notion 2.0 «Текущая дата – конечная дата диапазона»

Для корректного отображения диапазонов на диаграмме Ганта (Timeline) необходимо указать свойство «Формула» в качестве источника данных: ⋯ слева от синей кнопки New → Layout → Timeline → Show timeline by.

В этой формуле используются: prop, empty, not, if, lets, dateEnd, dateRange, dateStart.

Дата сегодня?

/* https://notionformulas.chumakova.ru */prop("Дата") == today()

/* https://notionformulas.chumakova.ru */equal(prop("Дата"), today())

/* https://notionformulas.chumakova.ru */prop("Дата").equal(today())

Скриншот от 09.06.2024

В этой формуле используются: prop, ==, equal.

Сегодня в диапазоне?

/* https://notionformulas.chumakova.ru */let(
	format, "YYYYMMDD",
	prop("Дата").dateStart().formatDate(format).parseDate() <= today() &&
	today() <= prop("Дата").dateEnd().formatDate(format).parseDate()
)

Скриншот от 09.06.2024

В этой формуле используются: let, prop, dateStart, formatDate, parseDate, <=, && (and), dateEnd.

Дата завтра?

Для данной формулы доступен только предпросмотр. Формула предназначена для демонстрации возможностей Notion. Научиться писать сложные формулы Notion можно в ходе онлайн-курса «Формулы Notion 2.0» от автора этого справочника.

Скриншот от 09.06.2024

Дата завтра или позднее?

/* https://notionformulas.chumakova.ru */formatDate(prop("Дата и время"), "YYYYMMDD") > formatDate(today(), "YYYYMMDD")

/* https://notionformulas.chumakova.ru */prop("Дата и время").formatDate("YYYYMMDD") > today().formatDate("YYYYMMDD")

Формула Notion 2.0 «Дата завтра или позднее?»

Скриншот от 09.06.2024

В этой формуле используются: prop, >.

Дата вчера?

Скриншот от 09.06.2024

Дата вчера или ранее?

/* https://notionformulas.chumakova.ru */formatDate(prop("Дата и время"), "YYYYMMDD") < formatDate(today(), "YYYYMMDD")

/* https://notionformulas.chumakova.ru */prop("Дата и время").formatDate("YYYYMMDD") < today().formatDate("YYYYMMDD")

Формула Notion 2.0 «Дата вчера или ранее?»

Скриншот от 09.06.2024

В этой формуле используются: prop, <.

Дата на этой календарной неделе?

/* https://notionformulas.chumakova.ru */formatDate(prop("Дата"), "YYYYWW") == formatDate(today(), "YYYYWW")

/* https://notionformulas.chumakova.ru */prop("Дата").formatDate("YYYYWW") == today().formatDate("YYYYWW")

Формула Notion 2.0 «Дата на этой календарной неделе?»

Скриншот от 09.06.2024

В этой формуле используются: formatDate, prop, ==.

Дата на следующей календарной неделе?

Скриншот от 09.06.2024

Дата на следующей календарной неделе или позднее?

Скриншот от 09.06.2024

Дата на предыдущей календарной неделе?

Скриншот от 09.06.2024

Дата на предыдущей календарной неделе или ранее?

Скриншот от 09.06.2024

Календарь на карточке

Скриншот от 13.06.2024.

Трекер привычек в виде календаря

Формула формирует и выводит календарь текущего месяца, включая номера календарных недель. Нажатие на кнопку «Сделано» добавляет запись в базу с отметками о выполнении, после чего ячейка соответствующего дня окрашивается в цвет привычки, в ячейке проставляется галочка.

Скриншот от 28.06.2024