Оператор == – равенство | Формулы Notion 2.0

Синтаксис

==

Возвращает Boolean.

Хотите чувствовать себя в Notion как рыба в воде?

Подпишитесь на канал автора сайта «Формулы Notion 2.0» с обзорами новых функций, советами начинающим и продвинутым пользователям, шаблонами, видеоуроками и эксклюзивными формулами! Перейти

Особенности

У оператора равенства == есть функция-синоним: equal.

У оператора равенства == есть антоним: !=.

Оператор == в формулах Notion выполняет проверку на строгое равенство: возвращает true при совпадении не только значений, но и типов данных, false, если обнаружено несовпадение хотя бы одного из двух.

25 формул Notion на каждый день

Бесплатный шаблон для Notion с подборкой из 25 востребованных формул от автора сайта «Формулы Notion 2.0». Перейти

Использование

Проверка значений на равенство

/* https://notionformulas.chumakova.ru */prop("Значение 1") == prop("Значение 2") /* Оператор */

/* https://notionformulas.chumakova.ru */equal(prop("Значение 1"), prop("Значение 2")) /* Функция */

/* https://notionformulas.chumakova.ru */prop("Значение 1").equal(prop("Значение 2")) /* Функция */

Формула Notion 2.0 «Проверка значений на равенство»

В этой формуле используются: prop, equal.

Дата сегодня?

/* https://notionformulas.chumakova.ru */prop("Дата") == today()

/* https://notionformulas.chumakova.ru */equal(prop("Дата"), today())

/* https://notionformulas.chumakova.ru */prop("Дата").equal(today())

Скриншот от 09.06.2024

В этой формуле используются: prop, today, equal.

Дата на этой календарной неделе?

/* https://notionformulas.chumakova.ru */formatDate(prop("Дата"), "YYYYWW") == formatDate(today(), "YYYYWW")

/* https://notionformulas.chumakova.ru */prop("Дата").formatDate("YYYYWW") == today().formatDate("YYYYWW")

Формула Notion 2.0 «Дата на этой календарной неделе?»

Скриншот от 09.06.2024

В этой формуле используются: formatDate, prop, today.

Автостатус задачи

/* https://notionformulas.chumakova.ru */prop("Выполнена?").if(
	"✅ Выполнена",
	lets(
		deadline, prop("Крайний срок").formatDate("YYYYMMDD").parseDate(),
		today, today(),
		ifs(
			today > deadline, "🔴 Просрочена",
			today == deadline, "🟡 Крайний срок – сегодня",
			"⚪️ Ожидает выполнения"
		)
	)
)

Скриншот от 25.05.2024.

В этой формуле используются: prop, if, lets, formatDate, parseDate, today, ifs, >.

Автостатус с просрочкой в днях

/* https://notionformulas.chumakova.ru */lets(
	interval, dateBetween(
		prop("Крайний срок").formatDate("YYYYMMDD").parseDate(), 
		today(), 
		"days"
	),
	sign, interval.sign(),
	ifs(
		sign == -1, ("Просрочена на " + interval.abs() + " дн.").style("red"),
		sign == 1, "В запасе " + interval + " дн.",
		sign == 0, "Крайний срок – сегодня",
		""
	)
)

Скриншот от 09.06.2024.

В этой формуле используются: lets, dateBetween, prop, formatDate, parseDate, today, sign, ifs, abs, style, + (сложение).