Как рассчитать процент?

Проценты в формулах Notion

Конфигурация формулы зависит от того, откуда берутся данные для расчета процента. Ниже представлены наиболее часто используемые формулы Notion для расчета процента.

Формулы для вывода процента в числовом формате должны возвращать целое или дробное число. В свойстве с формулой должен использоваться процентный формат отображения числа: клик по названию столбца → Edit property → Number format → Percent.

Процентный формат вывода – справочник формул Notion 2.0 с примерами 290 166

Представленные ниже приемы подробно рассматриваются в видео «Проценты в Notion».

Процент выполнения (Number)

Для получения процента необходимо разделить значение из свойства «Завершено» на значение из свойства «Всего».

/* https://notionformulas.chumakova.ru */prop("Завершено") / prop("Всего")

В этой формуле Notion используются: prop, /.

Процент из значений в свойствах Number – справочник формул Notion 2.0 с примерами 420 161

Процент завершенных подзадач (Checkbox)

Для получения процента завершенных задач, состояние которых фиксируется в свойстве Checkbox, необходимо получить количество выполненных подзадач в рамках задачи, общее количество подзадач в рамках задачи, а затем разделить первое на второе.

Подсчет процента осуществляется на уровне задачи, а на уровне подзадачи выполняется проверка значения в свойстве Checkbox.

/* https://notionformulas.chumakova.ru */if(
	empty(prop("Родительское")),
	lets(
		total, length(map(prop("Дочернее"), index)),
		done, length(filter(prop("Дочернее"), current.prop("Завершена?"))),
		done / total
	),
	if(
		prop("Завершена?"),
		1,
		0
	)
)

/* https://notionformulas.chumakova.ru */prop("Родительское").empty().if(
	lets(
		total, prop("Дочернее").map(index).length(),
		done, prop("Дочернее").filter(current.prop("Завершена?")).length(),
		done / total
	),
	prop("Завершена?").if(
		1,
		0
	)
)

В этой формуле Notion используются: if, empty, prop, lets, length, map, filter, /.

Процент из значений в свойстве Checkbox – справочник формул Notion 2.0 с примерами 726 375

Процент завершенных подзадач (Status)

Логика этой формулы Notion аналогична логике предыдущей за тем исключением, что анализируются значения не из свойства Checkbox, а из свойства Status.

/* https://notionformulas.chumakova.ru */if(
	empty(prop("Родительское")),
	lets(
		total, length(map(prop("Дочернее"), index)),
		done, length(filter(prop("Дочернее"), current.prop("Статус") == "Завершена")),
		done / total
	),
	if(
		prop("Статус") == "Завершена",
		1,
		0
	)
)

/* https://notionformulas.chumakova.ru */prop("Родительское").empty().if(
	lets(
		total, prop("Дочернее").map(index).length(),
		done, prop("Дочернее").filter(current.prop("Статус") == "Завершена").length(),
		done / total
	),
	(prop("Статус") == "Завершена").if(
		1,
		0
	)
)

В этой формуле Notion используются: if, empty, prop, lets, length, map, filter, ==, /.

Процент из значений в свойстве Status – справочник формул Notion 2.0 с примерами 731 375

Процент полученных платежей

Для расчета процента полученных платежей необходимо разделить сумму полученных платежей на сумму заказа.

/* https://notionformulas.chumakova.ru */lets(
	total, prop("Сумма заказа"),
	paid, sum(map(prop("Платежи"), current.prop("Сумма платежа"))),
	paid / total
)

/* https://notionformulas.chumakova.ru */lets(
	total, prop("Сумма заказа"),
	paid, prop("Платежи").map(current.prop("Сумма платежа")).sum(),
	paid / total
)

В этой формуле Notion используются: lets, prop, sum, map, /.

Процент полученных платежей – справочник формул Notion 2.0 с примерами 528 406